[Tyvj1114 搭建双塔]

[题目来源]：VIjos

[关键字]：动态规划

[题目大意]：用n块水晶搭建两个塔，要求双塔必须一样高，问最大能达到的高度为多少。

//============================================================================================================

[分析]：用f[i,j]表示使用前i个水晶,建起高度差为j的双塔时,较矮的那个塔的最大高度是多少。这样的话,对于每一块水晶都有三种决策,不使用,放到高塔上,放到矮塔上.而放到矮塔上会有两种情况,一是使矮塔的高度超过了高塔,二是没有超过。具体如下:
if f[1-t,j]>f[t,j] then f[t,j]:=f[1-t,j];//不使用
if f[1-t,j]>f[t,j+h[i]] then f[t,j+h[i]]:=f[1-t,j];//高塔
if j>=h[i]//判断会不会使矮塔变成高塔
 then
 begin
　　if f[1-t,j]+h[i]>f[t,j-h[i]] then f[t,j-h[i]]:=f[1-t,j]+h[i];
 end//不会
 else
 begin
　　if f[1-t,j]+j>f[t,h[i]-j] then f[t,h[i]-j]:=f[1-t,j]+j;
 end;//会
 这样DP就可以了。边界是f[0,0]:=0;目标是f[n,0];
//出自tyvj1114题解

//==========================================================================================================

[代码]：

program Project1;
var
  n: longint;
  a, s: array[0..200] of longint;
  f: array[0..200,0..2500] of longint;

procedure init;
var
  i: longint;
begin
  readln(n);
  for i := 1 to n do read(a[i]);
  for i := 1 to n do s[i] := s[i-1]+a[i];
end;

procedure work;
var
  i, j: longint;
begin
  fillchar(f,sizeof(f),200);
  f[0,0] := 0;
  for i := 1 to n do
    for j := 0 to s[i] do
      begin
        if f[i-1,j] > f[i,j] then f[i,j] := f[i-1,j];
        if f[i-1,j] > f[i,j+a[i]] then f[i,j+a[i]] := f[i-1,j];
        if j >= a[i] then
          if f[i-1,j]+a[i] > f[i,j-a[i]] then f[i,j-a[i]] := f[i-1,j]+a[i];
        if j < a[i] then
          if f[i-1,j]+j > f[i,a[i]-j] then f[i,a[i]-j] := f[i-1,j]+j;
      end;
  if f[n,0] > 0 then writeln(f[n,0]) else writeln('Impossible');
end;

begin
  assign(input,'c:\1.in');reset(input);
  assign(output,'c:\1.out');rewrite(output);
  init;
  work;
  close(input);
  close(output);
end.