学习《Building Applications with FME Objects》之四从数据集读取要素

FMEOReader可以访问任何支持格式的数据。

FMEOReader返回两类要素：schema（模式）要素和数据要素，模式要素用于描述数据集模型。每种支持的格式都有一个模式，一个模式要素是一类要素的数据模型，模式要素描述属性、坐标系和几何要素类型。

本章可以学习到：

创建reader
打开reader
获取reader设置
获得活动reader信息
返回模式要素
返回数据要素
关闭reader

创建Reader

必须通过FMEOSession对象的createReader方法创建，如下

Dim fmeDirectives As FMEOStringArray
Set fmeDirectives = m_fmeSession.createStringArray
fmeDirectives.append ("OUTPUT_STATS")
fmeDirectives.append ("NO")
Set m_fmeReader = m_fmeSession.createReader("SHAPE", _
False, fmeDirectives)

格式类型表示是唯一的，用于控制reader的创建，些在createReader方法的第一个参数，SHAPE用于创建ESRI Shapefile reader，下面是它的描述：

注意：FME对象的读写取决于上表中的Reader/Writer行。

createReader第二个参数为布尔值，用于决定是否创建要素磁盘缓存，如果你的应用程序需要多次访问要素集，它将缓存以提高性能，多次访问数据集缓存则可以减少I/O请求，当缓存时，FME对象创建一个基于基于磁盘的空间索引以方便快速随机访问要素并允许高级空间和属性查询，

createReader第三个参数为字符串数组，包含下表中的参数，以名和值成对出现：

打开Reader

一旦创建了reader，就可以打开指定的数据集，下面代码SHAPE reader读取c:\shape：

Dim fmekeywords As FMEOStringArray
Set fmeKeywords = m_fmeSession.createStringArray
fmeKeywords.append(“MEASURES_AS_Z”)
fmeKeywords.append(“YES”)
fmeKeywords.append(“IDs”)
fmeKeywords.append(“roads.shp”)
fmeKeywords.append(“IDs”)
fmeKeywords.append(“rivers.shp”)
Call m_fmeReader.open(“c:\shape”, fmeKeywords)

第一个参数，对于ESRI Shapefile reader来说，需要一个数据集目录，其他的reader可能会需要一个数据集文件、数据库或URL，详细信息查看Quick Facts table。

第二个参数是一个字符串数组，名字和数值成对出现，控制reader的操作。

用户设置Reader参数

通过FMEODialog对象，简单的创建和打开一个新的reader，FMEODialog的sourcePrompt方法显示一个对话框并且获得用户的数据。

例如：

注意：FMEODialog对象仅仅用于WINDOWS平台，其他操作系统中不可用。

SourcePrompt方法返回用户指定的参数，将返回的参数再传递给FMEOSession的createReader和FMEOReader的open方法：

Public Sub SourcePrompt(sSourceDir As String)
    Dim fmeDialog As FMEODialog
    Dim fmeDirectives As FMEOStringArray
    Dim fmeKeywords As FMEOStringArray
    Dim sDataset As String
    Dim sFormat As String
    Dim bCompleted As Boolean
    Set fmeDialog = m_fmeSession.createDialog
    Set fmeDirectives = m_fmeSession.createStringArray
    Call fmeDirectives.append("LIMIT_FORMATS")
    Call fmeDirectives.append("MIF")
    bCompleted = fmeDialog.SourcePrompt("MIF", sSourceDir, _
                             sFormat, sDataset, fmeDirectives)
    If bCompleted = True Then
        Set m_fmeReader = m_fmeSession.createReader(sFormat, _
                          True, fmeDirectives)
        Set fmeKeywords = m_fmeSession.createStringArray
        Call m_fmeReader.open(sDataset, fmeKeywords)
        m_bReaderOpened = True
    End If
End Sub

下面是SourcePrompt方法的参数：

从活动的Reader中获取信息

用输入数据源会话框，最红用户可以从格式列表中选择格式，如果你的应用程序需要访问可用的格式列表，可以使用FMEODialog对象的getAvailableFormats方法。并且可以通过FMEODialog对象的getAvailableFormats方法获得可用格式的详细信息.

下面的代码显示一个对话框来显示指定Reader的全部信息：

Public Sub GetReaderInfo(ByVal sFormatName As String)
    Dim lPos As Long
    Dim sMsg As String
    Dim sDirection As String
    Dim bSpatialIndex As Boolean
    Dim fmeDialog As FMEODialog
    Dim fmeFormats As FMEOStringArray
    Dim fmeFormatInfo As FMEOStringArray
    Set fmeDialog = m_fmeSession.createDialog
    Set fmeFormats = m_fmeSession.createStringArray
    Set fmeFormatInfo = m_fmeSession.createStringArray
    Call fmeDialog.getAvailableFormats(fmeFormats)
    lPos = GetIndex(fmeFormats, sFormatName)
    If lPos = -1 Then
        sMsg = "Format not available: "

        sMsg = sMsg & sFormatName & vbCrLf
        MsgBox sMsg, vbOKOnly, "GetReaderInfo"
        Exit Sub
    End If
    Call fmeDialog.getFormatInfoEx(sFormatName, fmeFormatInfo)
    sMsg = "Format: " & sFormatName
    lPos = GetIndex(fmeFormatInfo, "FORMAT_LONG_NAME")
    sMsg = sMsg & vbCrLf & "Long Name: "
    sMsg = sMsg & fmeFormatInfo.element(lPos + 1)
    lPos = GetIndex(fmeFormatInfo, "DATASET_TYPE")
    sMsg = sMsg & vbCrLf & "Dataset Type: "
    sMsg = sMsg & fmeFormatInfo.element(lPos + 1)
    lPos = GetIndex(fmeFormatInfo, "INPUT_OUTPUT")
    sMsg = sMsg & vbCrLf & "Direction: "
    sMsg = sMsg & fmeFormatInfo.element(lPos + 1)
    lPos = GetIndex(fmeFormatInfo, "FILE_EXTENSIONS")
    sMsg = sMsg & vbCrLf & "File Filter: "
    sMsg = sMsg & fmeFormatInfo.element(lPos + 1)
    lPos = GetIndex(fmeFormatInfo, "COORD_SYSTEM_AWARE")
    sMsg = sMsg & vbCrLf & "Coordinate System Aware: "
    sMsg = sMsg & fmeFormatInfo.element(lPos + 1)
    lPos = GetIndex(fmeFormatInfo, "SOURCE_SETTINGS")
    sMsg = sMsg & vbCrLf & "Has Source Settings: "
    sMsg = sMsg & fmeFormatInfo.element(lPos + 1)
    lPos = GetIndex(fmeFormatInfo, "DESTINATION_SETTINGS")
    sMsg = sMsg & vbCrLf & "Has Destination Settings: "
    sMsg = sMsg & fmeFormatInfo.element(lPos + 1)
    lPos = GetIndex(fmeFormatInfo, "AUTOMATED_TRANSLATION")
    sMsg = sMsg & vbCrLf & "Supports Automated Translation: "
    sMsg = sMsg & fmeFormatInfo.element(lPos + 1)
    MsgBox sMsg, vbOKOnly, "GetReaderInfo"
End Sub

FMEODialog对象的getFormatInfoEx方法返回的信息为名字数值对，下列表格为名字列表:

关于FMEOReader对象的额外信息，可以用它的getProperties方法获得，例如：

Set fmeProperties = m_fmeSession.createStringArray
Call m_fmeReader.getProperties("fme_prop_spatial_index", _
fmeProperties)

读取模式（Schema）要素

在读取数据要素前，不需要强制读取模式要素仍然可以连续读取数据要素，每次调用readSchema方法返回一个schema要素，该方法返回True或False，下面代码将在日志中写入数据集的所有模式要素：

Public Sub LogSchemaFeatures()
    Dim bLastSchema As Boolean
    Dim fmeSchemaFeature As FMEOFeature
    bLastSchema = False
    Set fmeSchemaFeature = m_fmeSession.createFeature
    Do While bLastSchema = False
        bLastSchema = m_fmeReader.readSchema(fmeSchemaFeature)
        If bLastSchema = False Then
           Call m_fmeLogfile.logFeature(fmeSchemaFeature, 1, 1)
       End If
     Loop
End Sub

读数据要素

一旦你的程序创建并且打开reader，就准备开始读取数据要素，可以使用read方法，该方法一次返回一个要素，当没有要素被读取时返回TRUE，否则返回FALSE，下面代码示范用reader读取所有要并写入feature vector。

bEnd = False
Do While bEnd = False
    Set fmeDataFeature = m_fmeSession.createFeature
    bEnd = m_fmeReader.read(fmeDataFeature)
    If bEnd = False Then
        Call fmeFeatureVector.append(fmeDataFeature)
    End If
Loop

注意：每次调用read方法前都新建一个FMEOFeature对象，为了防止覆盖前一次读取的要素。

使用约束

通过执行简单的空间查询和属性查询，限制FME对象仅读取匹配的要素，在最后一个要素读取后，你的应用程序可以对输入要素使用setConstraints方法开始新的过滤。

通过setConstraints方法给FMEOFeature对象指定约束，用属性指定过滤用fme_search_type，下表为fme_search_type支持的值：